Commit: b7fcfcf18ec9223b800711a585388d3f49c110cc - pixiv_down (git)

A CLI tool for downloading from pixiv.net

Commit MetaInfo

• Revision: b7fcfcf18ec9223b800711a585388d3f49c110cc (tree)
• Zeit: 2023-10-29 18:41:39
• Autor: mio <stigma@disr...>
• Commiter: mio

Log Message

Move configuration to separate module

Slowly going around and breaking down the main file.

Ändern Zusammenfassung

• modified: source/app.d
• add: source/configuration.d

Diff

--- a/source/app.d
+++ b/source/app.d
@@ -24,6 +24,8 @@ import pixivd.types;
 
 import pixivd.client;
 
+import configuration;
+
 class ProgressMonitor
 {
     private       size_t currentPage = 1;
@@ -130,12 +132,6 @@ class ProgressMonitor
     }
 }
 
-struct Config
-{
-    string baseFolder;
-    Client client;
-}
-
 enum ExitCode
 {
    success            = 0,
@@ -172,48 +168,6 @@ private bool convertToString(size_t value, out string converted)
 }
 
 /**
- * Prompt for the PHPSESSID cookie.
- *
- * Returns: The entered input, with the leading and trailing whitespace
- *          stripped.
- */
-string askForSessionID()
-{
-    import std.stdio : readln, writeln, write;
-    import std.string : strip;
-
-    string ret = "";
-
-    writeln("========== NOTICE ==========");
-    writeln("No PHPSESSID value found.");
-    writeln("Please see the below instructions to find yours.");
-    writeln("https://codeberg.org/supercell/pixivd/src/branch/trunk/PHPSESSID");
-    writeln("============================");
-
-    while ("" == ret) {
-        write("Please enter your PHPSESSID: ");
-        ret = readln().strip();
-    }
-
-    return ret;
-}
-
-/**
- * Store the *sessionid* in the file located at *path*.
- *
- * Params:
- *   sessionid = The PHPSESSID cookie value to store.
- *   path = The location of the file to write the value to.
- */
-pragma(inline, true)
-void storeSessionID(string sessionid, string path)
-{
-    import std.stdio : File;
-
-    File(path, "w").writeln(sessionid);
-}
-
-/**
  * Set the modification and access date/time for the provided *illust*.
  *
  * Params:
@@ -311,7 +265,7 @@ void downloadIllust(ref Illustration illust, ref Config conf,
     import std.path : buildPath;
     import std.stdio : stderr;
 
-    const rawPath = buildPath(conf.baseFolder,
+    const rawPath = buildPath(conf.outputDirectory,
         illust.userId ~ "_" ~ illust.userName);
     const subDirectory = makeSafe(rawPath);
 
@@ -1144,85 +1098,6 @@ logLibGMVersion()
    infof("GraphicsMagick Depth   S: %s", MagickQuantumDepth);
 }
 
-void
-resetSessionID()
-{
-   import std.file : exists, mkdirRecurse;
-   import std.path : buildPath;
-
-   import directories : ProjectDirectories, getProjectDirectories;
-
-   const projectDirectories = getProjectDirectories(null, "YumeNeru",
-      "pixiv_down");
-   if (false == exists(projectDirectories.dataDir))
-   {
-      mkdirRecurse(projectDirectories.dataDir);
-   }
-   const sessionid = askForSessionID();
-   storeSessionID(sessionid,
-      buildPath(projectDirectories.dataDir, ".phpsessid"));
-}
-
-Config
-loadConfig()
-{
-   import std.experimental.logger : infof;
-   import std.file : exists, mkdirRecurse;
-   import std.path : buildPath;
-   import std.string : strip;
-   import std.stdio : File;
-
-   import configparser : ConfigParser;
-   import directories : ProjectDirectories, UserDirectories,
-      getProjectDirectories, getUserDirectories;
-
-   Config config;
-
-   ProjectDirectories dirs = getProjectDirectories(null, "YumeNeru Software",
-      "pixiv_down");
-   UserDirectories userDirs = getUserDirectories();
-   infof("Configuration Directory = %s", dirs.configDir);
-
-   if (exists(dirs.configDir)) {
-      string configFilePath = buildPath(dirs.configDir, "settings.conf");
-      if (exists(configFilePath)) {
-         scope parser = new ConfigParser();
-         parser.read(configFilePath);
-         config.baseFolder = parser.get("output", "base_folder",
-            userDirs.pictureDir);
-      } else {
-         config.baseFolder = userDirs.pictureDir;
-      }
-   } else {
-      // Set default values
-      config.baseFolder = userDirs.pictureDir;
-   }
-   infof("Output Directory = %s", config.baseFolder);
-   infof("Local Data Directory = %s", dirs.dataDir);
-
-   const idFilePath = buildPath(dirs.dataDir, ".phpsessid");
-
-   if (!exists(idFilePath))
-   {
-      resetSessionID();
-   }
-
-   const sessionid = File(idFilePath).readln().strip();
-
-   if (null is sessionid)
-   {
-      scope newID = askForSessionID();
-      storeSessionID(newID, idFilePath);
-      config.client = new Client(newID);
-   }
-   else
-   {
-      config.client = new Client(sessionid);
-   }
-
-   return config;
-}
-
 /*
  * --------------------------------------------------------------------------
  *                                  Main
@@ -1236,7 +1111,7 @@ int
 main(string[] args)
 {
    import std.stdio : stderr, writeln, writefln;
-   import std.experimental.logger : stdThreadLocalLog;
+   import std.experimental.logger : stdThreadLocalLog, infof;
    import logger;
 
 version(appimage) {
@@ -1302,6 +1177,10 @@ version (GMagick_Dynamic) {
    logLibGMVersion();
 
    Config config = loadConfig();
+   debug { pragma(msg, "TODO: Remove Config.client"); }
+   config.client = new Client(config.sessionid);
+
+   infof("Output Directory = %s", config.outputDirectory);
 
    return (*func)(args, config);
 }

--- /dev/null
+++ b/source/configuration.d
@@ -0,0 +1,166 @@
+/*
+ * pixiv_down - CLI-based downloading tool for https://www.pixiv.net.
+ * Copyright (C) 2023  Mio
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation, version 3 of the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program.  If not, see <https://www.gnu.org/licenses/>.
+ */
+module configuration;
+
+private enum ProjectQualifier = null;
+private enum ProjectOrg = "YumeNeru Software";
+private enum ProjectName = "pixiv_down";
+private enum PHPSessionIDFileName = ".phpsessid";
+
+/// pixiv_down configuration.
+///
+/// Use `configuration.loadConfig` to load the correct values.
+struct Config
+{
+   /// The directory where content is downloaded to.
+   string outputDirectory;
+   /// The PHPSESSID of the current account.
+   string sessionid;
+
+   import pixivd : Client; // TODO: Remove/Replace
+   Client client;
+}
+
+/// Load the configuration for pixiv_down.
+Config loadConfig()
+{
+   return Config(fetchOutputDirectory(), fetchSessionID());
+}
+
+/// Prompt to reset the PHPSESSID.
+///
+/// This will store the value in the appropriate location so it
+/// can be read in the future.
+public void resetSessionID() @trusted /* @safe -> getProjectDirectories */
+{
+   import std.path : buildPath;
+   import directories : getProjectDirectories;
+
+   const projectDirs = getProjectDirectories(ProjectQualifier, ProjectOrg, ProjectName);
+   const id = promptForSessionID();
+
+   storeSessionID(id, buildPath(projectDirs.dataDir, PHPSessionIDFileName));
+}
+
+private string fetchOutputDirectory() /* @safe */
+{
+   import std.file : exists;
+   import std.path : buildPath;
+   import std.string : empty;
+
+   import configparser : ConfigParser;
+   import directories : getProjectDirectories, getUserDirectories;
+
+   const projectDirs = getProjectDirectories(ProjectQualifier, ProjectOrg, ProjectName);
+   const userDirs = getUserDirectories();
+
+   if (exists(projectDirs.configDir))
+   {
+      const configFile = buildPath(projectDirs.configDir, "settings.conf");
+      if (exists(configFile)) {
+         scope parser = new ConfigParser();
+         parser.read(configFile);
+
+         // COMPAT FOR <0.2 (REMOVE @ 0.3)
+         const outputDirectory = parser.get("output", "directory", "");
+         if (empty(outputDirectory))
+         {
+            import std.stdio : stderr;
+            stderr.writeln("Warning: output.base_folder configuration option is being removed.");
+            stderr.writeln("         Please use output.directory instead.");
+            stderr.writeln("From:");
+            stderr.writeln("\t[output]\n\tbase_folder = /my/path");
+            stderr.writeln("To:");
+            stderr.writeln("\t[output]\n\tdirectory = /my/path");
+
+
+            const baseFolder = parser.get("output", "base_folder", userDirs.pictureDir);
+            //parser.set("output", "directory", baseFolder);
+            // TODO: Write the new config file when `.write` is implemented.
+            return baseFolder;
+         }
+         return outputDirectory;
+      }
+   }
+
+   return userDirs.pictureDir;
+}
+
+private string promptForSessionID() @trusted
+{
+   import std.stdio : readln, stderr, write;
+   import std.string : empty, strip;
+
+   import core.stdc.stdlib : exit;
+
+   stderr.writeln("========== NOTICE ==========");
+   stderr.writeln("No PHPSESSID found.\n");
+   stderr.writeln("Please see the below webpage for instructions to find your PHPSESSID");
+   stderr.writeln("https://codeberg.org/supercell/pixivd/src/branch/trunk/PHPSESSID");
+   stderr.writeln("============================");
+
+   write("\nPlease enter your PHPSESSID (leave blank to exit): ");
+
+   const sessionid = readln.strip;
+
+   if (empty(sessionid))
+   {
+      exit(0);
+   }
+
+   return sessionid;
+}
+
+pragma(inline, true)
+private void storeSessionID(const(char)[] sessionid, const(char)[] path) @safe
+{
+   import std.stdio : File;
+
+   File(path, "w+").writeln(sessionid);
+}
+
+private string fetchSessionID() /* @safe */
+{
+   import std.file : exists, mkdirRecurse;
+   import std.path : buildPath;
+   import std.stdio : File;
+   import std.string : empty, strip;
+
+   import directories : getProjectDirectories;
+
+   const projectDirs = getProjectDirectories(ProjectQualifier, ProjectOrg, ProjectName);
+   const sessidPath = buildPath(projectDirs.dataDir, PHPSessionIDFileName);
+
+   if (false == exists(sessidPath))
+   {
+      mkdirRecurse(projectDirs.dataDir);
+      const newID = promptForSessionID();
+      storeSessionID(newID, sessidPath);
+      return newID;
+   }
+
+   const sessionid = File(sessidPath).readln.strip;
+
+   if (empty(sessionid))
+   {
+      const newID = promptForSessionID();
+      storeSessionID(newID, sessidPath);
+      return newID;
+   }
+
+   return sessionid;
+}